» Veranstaltungen
» Navigation
» über uns
|
» Registrierung
Liebe Mitleserinnen, Mitleser, Foristinnen und Foristen,
wer sich von Euch in letzter Zeit mit dem Gedanken getragen hat, Mitglied unseres wunderbaren IGDH-Forums zu werden und die vorher an dieser Stelle beschriebene Prozedur dafür auf sich genommen hat, musste oftmals enttäuscht feststellen, dass von unserer Seite keine angemessene Reaktion erfolgte.
Dafür entschuldige ich mich im Namen des Vereins!
Es gibt massive technische Probleme mit der veralteten und mittlerweile sehr wackeligen Foren-Software und die Freischaltung neuer User ist deshalb momentan nicht mit angemessenem administrativem Aufwand möglich.
Wir arbeiten mit Hochdruck daran, das Forum neu aufzusetzen und es sieht alles sehr vielversprechend aus.
Sobald es dies bezüglich Neuigkeiten, respektive einen Zeitplan gibt, lasse ich es Euch hier wissen.
Das wird auch für alle hier schon registrierten User wichtig sein, weil wir dann mit Euch den Umzug auf das neue Forum abstimmen werden.
Wir freuen uns sehr, wenn sich die geneigten Mitleserinnen und Mitleser, die sich bisher vergeblich um eine Freischaltung bemüht haben, nach der Neuaufsetzung abermals ein Herz fassen wollen und wir sie dann im neuen Forum willkommen heißen können.
Herzliche Grüße von Eurem ersten Vorsitzenden der IGDH
Rainer Feile
-
Tipp: Lautstärkeregelung am Windows-PC mit Shortcuts / Maus
Für den der noch keine praktische Lösung hat die Lautstärke schnell mit einem Hotkey (auf jeder normalen Tastatur) und mit grafischer Ansicht des Volume-Levels zu sehen evtl. eine nette Option. Grafisch nicht fürchterlich attraktiv, aber sehr praktisch sieht man welche Lautstärke gerade eingestellt ist und wenn die gemutet ist (roter Balken), so erkennt man trotzdem die aktuelle Einstellung (die auch gemutet veränderbar ist!):
Hab eben die Idee von https://www.autohotkey.com/boards/vi...47784&start=40 "geklaut" und minimal angepasst, so dass man mit den Windows+Pfeil-Tasten hoch bzw. runter die Lautstärke ändert und mit der Pause-Taste mutet/unmutet. Ich will manchmal den Ton möglichst schnell leise bekommen, daher hab' ich es so eingerichtet, dass die Windows-Pfeilrunter-Taste den Ton um zwei Schritte verkleinert und die Pfeil-Hoch-Taste einen Schritt erhöht. Das finde ich sehr praktisch.
Man braucht dazu Autohotkey und muss folgendes Skript unter beliebigem Namen, z. B. Volume-Regler.ahk abspeichern. Dann sollte man dazu eine Verknüpfung im Autostart-Menü erstellen. Gefallen die gewählten Tastenkürzel nicht, so kann man die leicht abändern (siehe Beginn des Skripts und in der Doku zu Autohotkey, (^!m würde z.B. Ctrl-Alt-M bedeuten) oder auch auf die Maus oder das Mausrad legen, wenn man das lieber mag.
Oh, sehe gerade man kann hier keine Dateien hochladen. Daher kurz über we-transfer, wer kein Autohotkey installieren oder sonst nutzen mag aber mal so schnell probieren will kann dort eine ausführbare Datei herunter laden (für eine Woche verfügbar): https://we.tl/t-HsMEyTpMYA
Off-Topic: Ich benutze Autohotkey schon "ewig", um alle möglichen Anpassungen für die Tastatur zu machen oder Zeug zu automatisieren. Wer es nicht kennen sollte, sicher einen Blick wert.
Code:
; Joe Winograd 27-Aug-2018
; Developed for Windows 10, but tested successfully on W7, W8.1, and W10 (all 64-bit)
; Updated with Toggle Mute feature 10-Mar-2021
; Updated with Red and Green sliders for Muted and Unmuted states 10-Mar-2021
; 2021-03-14 PK: changed default hotkey to Win-Up and Win-Down and Pause
; added decrease parameter step to allow faster turning down of the volume
#Warn,UseUnsetLocal
#NoEnv
#SingleInstance force
SetBatchLines,-1
; begin values to change
BarWidth:="w800"
BarHeight:="h20"
BarXlocation:="x500"
BarYlocation:="y1200"
BarColorMuted:="Red"
BarColorUnmuted:="Green"
BarMillisecondsToStayOnScreen:=1000 ; 1 second
HotkeyVolumeDown:="#Down"
HotkeyVolumeUp:="#Up"
HotkeyToggleMute:="Pause"
;HotkeyVolumeDown:="NumpadSub"
;HotkeyVolumeUp:="NumpadAdd"
;HotkeyToggleMute:="NumpadMult"
VolumeIncrement:=1
VolumeDecrement:=2
; end values to change
SplitPath,A_ScriptName,,,,ProgramName
Hotkey,%HotkeyVolumeDown%,VolumeDown
Hotkey,%HotkeyVolumeUp%,VolumeUp
Hotkey,%HotkeyToggleMute%,ToggleMute
SoundGet,Volume
Volume:=Round(Volume)
TrayTip:=HotkeyVolumeDown . " or " . HotkeyVolumeUp . " to adjust volume" . "`n" . HotkeyToggleMute . " to toggle mute" . "`nCurrent Volume=" . Volume
TrayIconFile:=A_WinDir . "\System32\shell32.dll" ; get tray icon from shell32.dll
TrayIconNum:="-225" ; use music note as tray icon (icon 225 in shell32)
Menu,Tray,Tip,%TrayTip%
Menu,Tray,Icon,%TrayIconFile%,%TrayIconNum%
Gui,+ToolWindow -SysMenu
Gui,Add,Progress,%BarWidth% %BarHeight% c%BarColor% vBarVal
Gui,Hide
Return ; end auto-execute
VolumeDown:
SetTimer,SliderOff,%BarMillisecondsToStayOnScreen%
SoundSet,-%VolumeDecrement%
Gosub,DisplaySlider
Return
VolumeUp:
SetTimer,SliderOff,%BarMillisecondsToStayOnScreen%
SoundSet,+%VolumeIncrement%
Gosub,DisplaySlider
Return
ToggleMute:
SoundSet,+1,,Mute ; toggle the mute setting
Return
SliderOff:
Gui,Hide
Return
DisplaySlider:
SoundGet,MuteState,,Mute
If (MuteState="Off")
BarColor:=BarColorUnmuted
Else
BarColor:=BarColorMuted
SoundGet,Volume
Volume:=Round(Volume)
Title:=ProgramName . " Current Volume=" . Volume
Gui,Show,%BarXlocation% %BarYlocation%,%Title%
GuiControl,,BarVal,%Volume%
GuiControl,+c%BarColor%,BarVal
TrayTip:=HotkeyVolumeDown . " or " . HotkeyVolumeUp . " to adjust volume" . "`n" . HotkeyToggleMute . " to toggle mute" . "`nCurrent Volume=" . Volume
Menu,Tray,Tip,%TrayTip%
Return
Geändert von rpnfan (14.03.2021 um 12:34 Uhr)
Forumregeln
- Es ist dir nicht erlaubt, neue Themen zu verfassen.
- Es ist dir nicht erlaubt, auf Beiträge zu antworten.
- Es ist dir nicht erlaubt, Anhänge hochzuladen.
- Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.
-
Foren-Regeln
|